PSPICE Simulation

The circuit used for Pspice simulation is shown below. All the nodes other than the datum node are connected to the datum node through a 1 MW resistor. A floating node or a node that tends to float can be a problem for Pspice simulation.

The program is presented below.

* Full-wave Bridge Rectifier with a resistive load
VIN 1 0 SIN(0 340V 50Hz)
XT1 1 2 5 2 SCR
XT2 0 2 6 2 SCR
XT3 3 0 7 0 SCR
XT4 3 1 8 1 SCR
VP1 5 2 PULSE(0 10 1667U 1N 1N 100U 20M)
VP2 6 2 PULSE(0 10 11667U 1N 1N 100U 20M)
VP3 7 0 PULSE(0 10 1667U 1N 1N 100U 20M)
VP4 8 1 PULSE(0 10 11667U 1N 1N 100U 20M)
R1 2 3 10
R2 1 0 1MEG
R3 2 0 1MEG
R4 3 0 1MEG

* Subcircuit for SCR
.SUBCKT SCR 101 102 103 102
S1 101 105 106 102 SMOD
RG 103 104 50
VX 104 102 DC 0
VY 105 107 DC 0
DT 107 102 DMOD
RT 106 102 1
CT 106 102 10U
F1 102 106 POLY(2) VX VY 0 50 11
.MODEL SMOD VSWITCH(RON=0.0105 ROFF=10E+5 VON=0.5 VOFF=0)
.MODEL DMOD D((IS=2.2E-15 BV=1200 TT=0 CJO=0)
.ENDS SCR
.TRAN 10US 60.0MS 20.0MS 10US
.FOUR 50 V(2,3) I(VIN)
.PROBE
.OPTIONS(ABSTOL=1N RELTOL=.01 VNTOL=1MV)
.END

The waveforms obtained are presented below.

The voltage waveform across the load resistor

The voltage waveform across SCR1

The average load current

The Frequency spectrum of line current

The Frequency spectrum of output voltage